betle

• --ROOT : 최상위 뿌리노드를 의미
  
  
• --절 : 종속/의존 관계에 있는 <문장>을 의미
• --문 : 하나의 독립적인 <문장>을 의미
  
  
• --구 : <부>와 <항>의 집합
• --부 : <항> 또는 <군>의 집합 또는
• --항 : <지정자>로 시작하는 단위
  
  
• --군 : <토큰>또는 <문장>이 <연결사>에 의해서 대등한 관계로 뭉친 것
• --속 : <토큰>또는 <문장>이 상대적인 상하관계로 뭉친 것
  
  
• --자 : 문장요소<토큰>
• --사 : 품사<토큰>
  
  
  
  

문장은 최상위 구조(ROOT)이며 다음과 같이 광역연결사로 시작할 수 있고 또한 광역연결사에 의해 거듭 연장될 수 있고 문종료자에 의해 종료된다.

• <ROOT> ::= <<ㅏたО沼>> ( ( <연결문> <문종료자> ) | <괄호문> )
  
  
  

연결문과 괄호문은 주로 종속절에서 사용하게 된다.

괄호문은 양쪽에 괄호로 둘러쌓인 문장이고 연결문은 양쪽에 괄호없이 이어진 문장을 의미한다.

• <괄호문> ::= <좌괄호> <문장군> <우괄호>
  
  
• <연결문> ::= <본문> { { <광역연결사> <문장군> } <광역연결사> <본문> }
  
  

문장군은 여러 개의 본문이 광역연결사에 의해 연결된 문장을 말하고 광역연결사의 영역을 괄호로 제한할 수 있다.

• <문장군> ::= <문장군> { <광역연결사> <문장군> }
  
  
• <문장군> ::= <좌괄호> <문장군> <우괄호>
  
  
• <문장군> ::= <본문>
  
  
  

메타절은 일반문장과 크게 다르지 않지만 반드시 <메타술어구>로 끝나야 한다.

본문의 경우 지정자가 있는 항이 아닌 명사군에서 바로 문장이 시작할 수 있는데 이런 경우 이 명사의 문장성분은 거의 추정에 의존하게 되는데 독립항( 대표어, 부연 )에 가깝거나 주어로 사용된다고 보아야 한다.

메타절의 주어와 술어사이에는 독립구만이 끼어들 수 있다.

• <본문> ::= {<선두구>} {<메타절>} <소문>
  
  
• <메타절> ::= {<메타구>} <메타술어구>
  
  
• <메타구> ::= <메타정형구> | <독립구>
  
  
• <메타정형구> ::= <선행부> ( <메타주어항> | <목적항> ) <후행부>
  
  
• <메타술어구> ::= { <선행부사어부> } <메타술어항> { <후행부사어부> }
  
  
  

본문은 하나의 소문 또는 이어진 소문으로 만들어 진다. 소문은 작은 문장으로 연결사가 없는 하나의 독립가능한 문장을 의미한다. 소문은 정형구와 동형구, 부연구의 집합으로 볼수 있는데 정형구는 주어,목적어,표제어 등의 영역에 해당하고 동형구는 서술어의 영역에 해당한다.

본문은 다만 소문앞에 메타절이 있는 것을 의미한다.

• <소문> ::= { <정형구> | <동형구> | <독립구> } 1-
  
  

• <정형구> ::= <선행부> <정형항> <후행부>
  
  
  
• <동형구> ::= <선행부사어부> <동형항> <후행부사어부>
  
  

선두구는 광역연결사 바로 뒤나 문장의 첫부분에만 올 수 있다. 선두구와 정형구, 메타정형구는 관형어 부사어 관계없이 수식을 받을 수 있다. 단 선두구는 후행만을 지원한다. 이는 선두구는 앞에 지정사가 오지 않기 때문이다. 메타정형항은 정형항과 주어항만 다르다.

• <선두구> ::= <명사군> <후행부>
  
  
• <독립구> ::= <독립항>
  
  
  
• <선행부> ::= <선행관형어부> | <선행부사어부>
• <후행부> ::= <후행관형어부> | <후행부사어부>
  
  
  
• <정형항> ::= <주어항> | <목적항>
  
  
• <목적항> ::= <목적어항> | <제2목적어항> | <대표어항>
  
  
• <동형항> ::= <술어항>
  
  
• <독립항> ::= <부연항> | <대입어항>
  
  
  
  

• <주어항> ::= <주어지정자> <명사군>
• <목적어항> ::= <목적어지정자> <명사군>
• <제2목적어항> ::= <제2목적어지정자> <명사군>
• <대표어항> ::= <대표어지정자> <명사군>
  
  
  

명사군은 정형항에서 쓰이고 술어군은 동형항에서 쓰인다. 둘 모두 협역연결사를 이용할 수 있는데 명사군에서는 생략할수 있으나 동형항에서는 생략될 수 없다.

• <명사군> ::= <명사속> {<<廈たО沼>><명사속>}
• <명사군> ::= <좌괄호> <명사군> <우괄호>
  
  
• <명사속> ::= { ( <일반명사> | <그룹> | <엑스코드> ) { <독립사> }} 1-
  
  

• <부연항> ::= <부연지정자><명사군>
• <대입어항> ::= <대입지정자><명사군>
  
  

• <메타주어항> ::= <메타주어지정자> <명사군>
• <메타술어항> ::= <메타술어지정자> <술어군>

• <술어항> ::= <술어지정자> <술어군>
  
  
• <술어군> ::= <술어속> { <협역연결사> <술어속> }
• <술어군> ::= <좌괄호> <술어군> <우괄호>
  
  
• <술어속> ::= { <보조동사속> } <동사속>
• <동사속> ::= <조동사속> <명사속>
  
  
• <보조동사속> ::= <보조동사> {<독립사>}
• <조동사속> ::= <조동사> {<독립사>}
  
  

• <선행관형어부> ::= { <관형어항> } 1-
• <후행관형어부> ::= <관형어군>
  
  
• <관형어항> ::= <관형어지정자> <관형어군>
  
  
• <관형어군> ::= <관형어속> { <협역연결사> <관형어속> }
• <관형어군> ::= <좌괄호> <관형어군> <우괄호>
  
  
• <관형어속> ::= { <술어속> | <관형어절> } 1-
  
  
• <관형어절> ::= <관형절접속사속> ( <괄호문> | <종속문> )
• <관형절접속사속> ::= <정형계관형절접속사속> | <부사어계관형절접속사속> | <관형어계관형절접속사속>
  
  
• <부사어계관형절접속사속> ::= <부사어계관형절접속사> <전치사>
  
  
• <관형어계관형절접속사속> ::= ( <관형어계관형절접속사> | <술어계관형절접속사> ) <<向底>>
  
  
• <정형계관형절접속사속> ::= <정형계관형절접속사> <명사군>
  
  

정형계관형절접속사 : 피수식구의 단어가 종속절에서 주어 , 목적어, 대표어로 사용될 경우

부사어계관형절접속사속 : 피수식구의 단어가 종속절에서 접속사와 결합할 부사어 역할을 하는 경우

관형어계관형절접속사속 : 피수식구의 단어가 종속절에서 조동사와 결합할 관형어 역할을 하는 경우

술어속은 관형어도 부사어도 될 수 있다. 즉 앞에 오는 항에 따라 달라지게 된다.

• <선행부사어부> ::= { <부사어항> } 1-
• <후행부사어부> ::= <부사어군>
  
  
• <부사어항> ::= <부사어지정자> <부사어군>
  
  
• <부사어군> ::= <부사어속> { <협역연결사> <부사어속> }
• <부사어군> ::= <좌괄호> <부사어군> <우괄호>
  
  
• <부사어속> ::= { <술어속> | <전치사속> | <부사어절> } 1-
  
  
• <전치사속> ::= <전치사> { <술어속> | <명사군> }
  
  
• <부사어절> ::= <부사절접속사> ( <괄호문> | <종속문> )
  
  
  
• <종속문> ::= <연결문> ( <절종료자> | <문종료자> # )
  
  

보류 : 현재 => 대입어항을 정형항에 포함하여 일반 문장의 일부가 되도록 하였다. 따라서 <대입문>은 없어지기 때문에 과 일반문장 을 구분하지 않아된다. 이는 대입이라는 요소는 파싱후 처리에 속하게 하였다.

// 대입문은 문장의 첫부분에 대입항만 추가된 것이다. 하나의 문장은 술어가 없는 경우도 있고 술어가 있는 경우도 있다. 한 문장 에 두 개의 대입어를 지정할수 있고 하나의 대입문은 안에 여러 개의 대입절을 가지고 있다.

CategoryBetleDev